自從改版之後，因為巨集的寫法有很大的改變，似乎有不少人哇哇叫的樣子
在此列出一些範例，如果有問題歡迎提出來討論

如果需要詳細的資訊的話，推薦參考以下連結
WOW API
HOWTO: Make a Macro
2.0 consolidated changes




但是在提出之前，請先看看以下這幾點，這邊先列兩種常常會被問的問題：

一、因為CastSpellByName()跟TargetUnit()這兩個指令被禁止用在巨集之中，所以有關判斷任何目標的體力、魔力、buff、debuff的功能，皆不能與技能作組合，講得白話點，也就是不能再以判斷目標的體力、魔力，或是有沒有中何種buff、debuff，來決定該使用什麼技能。

二、大部分的技能會觸發GCD（共同冷卻），而且不論是否施展成功都會觸發，所以不能將兩個會受到GCD影響的技能放在一起，然後期許因為第一個技能還不能使用而去使用第二技能。舉個簡單的例子，如果把破甲放在復仇的後面，不管復仇是不是可用，都保證破甲絕對用不出來。

如果說你的巨集跟上面兩種之一有關的話
必須要修改成以玩家自己判斷狀況的巨集
若堅持要保有原來的功能…
很對不起，那是無解的，請別提出來了


繼續追加常常被問的問題：

三、如果巨集沒有辦法顯示CD時間與說明，在巨集開始第一行加入以下這行即可

# showtooltip 道具或技能名稱

順便一提，現在設定巨集圖案(ICON)的時候，如果選擇第一個？圖案，而在巨集中又有# showtooltip或# show等指令的話，會自動對應成指定的道具或技能圖案。如果僅選擇第一個？圖案，而在巨集中沒有# showtooltip或# show等指令的話，則會選擇第一個/cast或/use系列中所指示的第一個技能或物品作為圖案。



========================== 廢話到此為止 ==============================
=============== 應該有不少人會直接略過上面直接往下看吧 ===============

通用的巨集：

發動攻擊，此巨集不會因為多點了一下而取消攻擊動作，要取消請愛用ESC。
# showtooltip 攻擊
/startattack


設定一個目標作為『focus』的對象。
顧名思義，『focus』就是設定用來『監控』一個目標。如此一來，即使目標常常換來換去，依然可以非常迅速地『監控』一個重要的目標，對於控場及治療有著很大的幫助。
/focus
/s %t！我正在監視你！


使用厚符文布繃帶。若是以右鍵點擊，則為自己的寵物使用；若不是以右鍵點擊，則是為一個友善的目標使用；若沒有友善目標，則是為自己使用。
/use [target=pet,button:2] 厚符文布繃帶;[help] 厚符文布繃帶; [target=player] 厚符文布繃帶


依序使用尋找藥草、尋找礦石，依此輪迴。此巨集只會在沒有進入戰鬥時使用以避免觸發GCD。
亦可將各種職業或種族的追蹤技能追加進去，如尋找寶箱、追蹤野獸等。
/castsequence [nocombat] 尋找草藥, 尋找礦物


取消一個Buff。除了坐騎以外都可以用這個。
/cancelaura Buff名稱


隨機選擇坐騎；若已經在騎乘狀態則解除坐騎。並在使用坐騎時講話。
/dismount [mounted]
/userandom [nomounted,nocombat,outdoors] 迅捷祖利安猛虎, 拉札希迅猛龍, 迅捷霧刃豹韁繩, 死亡軍馬的韁繩
/script if not IsMounted() then SendChatMessage("讓我想想…該用騎那一頭坐騎好呢…", "SAY");end;


裝備指定物品。
主手物品必須比副手物品先行裝備，否則從雙手武器切換時會有問題。
/equipslot 11 戒指１
/equipslot 12 戒指２
/equipslot 13 飾品１
/equipslot 14 飾品２
/equipslot 16 主手裝備
/equipslot 17 副手裝備


使用釣魚，若尚未裝備釣魚竿則裝備釣魚竿。如果以右鍵點擊，則是裝備回指定的武器。
/equip [nobutton:2,noequipped:魚竿] 釣魚竿
/cast [nobutton:2,equipped:魚竿] 釣魚
/equipslot [button:2] 16 主手裝備
/equipslot [button:2] 17 副手裝備



戰士巨集：

依照姿態的不同使用反擊風暴、盾牆或魯莽。同時大喊通知他人。
/cast [stance:1] 反擊風暴;[stance:2,equipped:盾牌] 盾牆;[stance:3] 魯莽
/script s={"反擊風暴！誰想挨揍的啊！","盾牆！硬梆梆的15秒！","魯莽！不要攔我！"};SendChatMessage(s[GetShapeshiftForm(true)], "YELL");


使用嘲諷，並在使用之前切換為防禦姿態（如果必要的話）。
# showtooltip 嘲諷
/cast [stance:2] 嘲諷; 防禦姿態

其他像壓制、拳擊、繳械等技能也可以照樣修改，注意[stance:1]是戰鬥姿態。[stance:3]是狂暴姿態
# showtooltip 懲戒痛擊
/cast [stance:1] 懲戒痛擊; 戰鬥姿態

# showtooltip 狂暴之怒
/cast [stance:3] 狂暴之怒; 狂暴姿態


在切換至戰鬥姿態以及裝備指定武器之後，使用壓制。
旋風斬也是一樣的格式，這裡就不列了。
# showtooltip 壓制
/equip [noequipped:雙手]爽手武器
/cast [stance:1,equipped:雙手] 壓制;[nostance:1] 戰鬥姿態


使用挫志怒吼，若是以右鍵點擊則使用雷霆一擊。
# showtooltip 雷霆一擊
/cast [button:2] 雷霆一擊; 挫志怒吼


若進入戰鬥狀態，則使用壓制；否則使用衝鋒。若是以右鍵點擊則同時使用英勇打擊。
# showtooltip 壓制
/cast [combat] 壓制; 衝鋒
/stopcasting [button:2]
/cast [button:2] 英勇打擊


使用致死打擊，若致死打擊尚在冷卻時間內則使用旋風斬。
有點強化致死的話，記得把6改成5。
/castsequence reset=6 致死打擊, 旋風斬


同時使用英勇打擊及破甲攻擊。
由於英勇打擊沒有GCD的問題，所以可以跟其他瞬發技能一起使用。
當然，怒氣要足夠～
# showtooltip 破甲攻擊
/cast 破甲攻擊
/stopcasting
/cast 英勇打擊

或者下面這個也是可行的，交替使用二個，只要狂按就好。
# showtooltip 破甲攻擊
/castsequence 英勇打擊, 破甲攻擊


如果有裝備盾而且是在戰鬥或防禦姿態就使用盾擊；否則使用拳擊，並於使用前切換到狂暴姿態（如果有必要的話）。
# showtooltip 拳擊
/cast [stance:1/2,equipped:盾牌] 盾擊;[stance:1/2,noequipped:盾牌] 狂暴姿態; 拳擊


若尚未進入戰鬥時切換為戰鬥姿態（如果必要的話），並使用衝鋒；若已經進入戰鬥時切換為狂暴姿態（如果必要的話），並使用攔截。
# showtooltip 攔截
/cast [stance:1,nocombat] 衝鋒;[nocombat] 戰鬥姿態; [stance:1/2] 狂暴姿態; 攔截


若『滑鼠所指的目標』為敵對目標，則對該目標使用破甲攻擊；否則對『眼前的目標』使用破甲攻擊。
透過這樣的實作就能在不需更換眼前的目標的前提下，對其他目標使用破甲攻擊。由於破甲攻擊沒有傷害的特性，所以即使用在被牽制（變形、媚惑…）的目標上也不會造成牽制失效。
# showtooltip 破甲攻擊
/cast [target=mouseover,exists,harm] 破甲攻擊; 破甲攻擊



牧師巨集：

使用復活術並通知他人。
台詞過長可能會發生問題，若出現錯誤訊息時試著縮短台詞或減少台詞種類即可。
# showtooltip 復活術
/script s={"台詞一","台詞二","台詞三","台詞四"};
/script if UnitExists("target") and UnitIsDeadOrGhost("target") then SendChatMessage(s[math.random(getn(s))], "SAY");end;
/cast 復活術


使用真言術：韌；若以右鍵點擊則使用堅韌禱言。
# showtooltip 堅韌禱言
/cast [button:2] 堅韌禱言; 真言術：韌


立即停止目前動作並使用沉默；如果目標不是敵對狀態，就對目標的目標使用（目標的目標必須為敵對狀態）。
# showtooltip 沉默
/stopcasting
/cast [harm] 沉默; [target=targettarget,harm] 沉默


對友善目標或敵對目標的友善目標使用強效治療術；若以右鍵點擊則對自己使用強效治療術。
# showtooltip 強效治療術
/cast [target=player,button:2] 強效治療術;[help] 強效治療術; [target=targettarget,help] 強效治療術


將『眼前的目標』設定為『監控的目標』並使用束縛不死生物。若以右鍵點擊，則直接對『監控的目標』使用束縛不死生物（若『監控的目標』已死亡或不存在，會自動將『眼前的目標』設定為『監控的目標』）。
透過這樣的實作之後，只需要在第一次進行束縛的時候注視著該目標，第二次之後就不必轉頭去看也能夠直接進行束縛。
# showtooltip 束縛不死生物
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [nobutton:2]
/focus [target=focus,noexists,button:2]
/cast [target=focus,button:2] 束縛不死生物; 束縛不死生物
/script SendChatMessage("正在對 "..UnitName("focus").." 施放束縛不死生物
","SAY");



獵人巨集：

使用獵豹守護，如果是以右鍵點擊則使用豹群守護。
# showtooltip 豹群守護
/cast [button:2] 豹群守護; 獵豹守護


使用毒蛇釘刺，如果是以右鍵點擊則使用蝮蛇釘刺，如果是以中鍵點擊則使用毒蠍釘刺。
# showtooltip 毒蛇釘刺
/cast [button:3] 毒蠍釘刺;[button:2] 蝮蛇釘刺; 毒蛇釘刺


使用假死，若假死尚在冷卻時間內則使用逃脫。戰鬥脫離之後自動重置。
# showtooltip 假死
/castsequence reset=30/combat 假死, 逃脫, 逃脫, 逃脫, 逃脫


對敵對目標使用獵人印記。若是以右鍵點擊，則同時命令寵物攻擊。若是在隊伍中，則通知隊友被標印記的目標為何。
若將「/stopmacro [nogroup]」改成「/stopmacro [nogroup:raid]」，則只有在raid中才會通知隊友。
# showtooltip 獵人印記
/cast [harm] 獵人印記
/stopmacro [noharm]
/petattack [pet,button:2]
/stopmacro [nogroup]
/y 攻擊目標為 %t


同時使用猛禽一擊及摔絆。
# showtooltip 猛禽一擊
/cast 摔絆
/stopcasting
/cast 猛禽一擊


如果以右鍵點擊或寵物雖存在但已死亡，使用復活寵物；如果寵物不存在，使用召喚寵物；如果寵物存在且在戰鬥中，使用治療寵物；如果寵物存在且不在戰鬥中，使用餵食寵物並使用指定食物。
# showtooltip 治療寵物
/cast [button:2,nocombat] 復活寵物;[target=pet,dead,nocombat] 復活寵物;[nopet] 召喚寵物;[combat] 治療寵物; 餵養寵物
/use [pet,nocombat] 食物名稱


命令寵物攻擊或協同同伴攻擊；如果以右鍵點擊則是召回寵物。
/petfollow [button:2]
/stopmacro [button:2]
/stopmacro [noexists]
/assist [help]
/petattack


將『眼前友善目標』設為『監控的目標』，如果『眼前的目標』並非友善目標，則將『目標的目標』設為『監控的目標』，同時使用誤導。
# showtooltip 誤導
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [help]
/focus [target=focus,noexists] targettarget
/clearfocus [target=focus,harm]
/cast [target=focus,exists] 誤導



聖騎士巨集：

使用力量祝福；如果以右鍵點擊則使用強效力量祝福。
# showtooltip 強效力量祝福
/cast [button:2] 強效力量祝福; 力量祝福


對友善目標或敵對目標的友善目標使用聖光術；如果以右鍵點擊則對自己使用。
# showtooltip 聖光術
/cast [target=player,button:2] 聖光術;[help] 聖光術; [target=targettarget,help] 聖光術


對友善目標或敵對目標的友善目標使用正義防禦。
# showtooltip 正義防禦
/cast [help] 正義防禦;[target=targettarget,help] 正義防禦


對敵對目標使用神聖震擊；或以右鍵點擊隊友善目標使用。
# showtooltip 神聖震擊
/cast [button:2,help] 神聖震擊;[harm] 神聖震擊


使用神恩術，並對敵對目標使用神聖震擊。若以右鍵點擊，則對友善目標使用神震擊。
# showtooltip 神恩術
/cast 神恩術
/stopcasting
/stopmacro [dead]
/cast [harm] 神聖震擊;[help,button:2] 神聖震擊



術士巨集：

用右鍵就是使用極效靈魂石；否則就是製造極效靈魂石。
# showtooltip 極效靈魂石
/cast [nobutton:2] 製造靈魂石
/stopmacro [nobutton:2]
/use [help] 極效靈魂石
/stopmacro [nohelp]
/y >>>%t<<<已經被我綁定了


若以右鍵點擊則對監控的目標使用詛咒三連星；否則眼前的目標使用詛咒三連星，同時將監控眼前的目標。
/clearfocus [target=focus,dead]
/clearfocus [target=focus,noexists]
/focus [nobutton:2]
/focus [target=focus,noexists,button:2]
/castsequence [target=focus,button:2] reset=combat/target 痛苦詛咒,腐蝕術,獻祭; reset=combat/target 痛苦詛咒,腐蝕術,獻祭



感謝巴哈-thundermare-大大