#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <oo_assets>

new Assets:g_oAssets;

public plugin_precache()
{
       // 建立物件
       g_oAssets = oo_new("Assets");

       // 为这物件读取 json (以下来说, 读取的位置就是 configs/assets/example.json)
       AssetsLoadJson(g_oAssets, "assets/example.json");
}

public plugin_init()
{
       register_plugin("Assets Exmaple", "0.1", "holla");

       RegisterHam(Ham_Item_Deploy, "weapon_knife", "OnKnifeDeploy_Post", 1);
       RegisterHam(Ham_TraceAttack, "worldspawn", "OnWorldSpawnTraceAttack_Post", 1);

       register_forward(FM_EmitSound, "OnEmitSound");
}

public OnKnifeDeploy_Post(ent)
{
       // 检查有效实体
       if (!pev_valid(ent))
              return;

       // 获取小刀的主人 (玩家id)
       new player = get_ent_data_entity(ent, "CBasePlayerItem", "m_pPlayer");
       if (!player)
              return;

       // 从资源物件中获取 "v_knife" 的模组档位置
       static model[32];
       if (AssetsGetModel(g_oAssets, "v_knife", model, charsmax(model)))
       {
              // 改变玩家的小刀模组
              set_pev(player, pev_viewmodel2, model);
       }
}

public OnWorldSpawnTraceAttack_Post(ent, attacker, Float:damage, Float:direction[3], tr, damagebits)
{
       // 检查有效攻击者
       if (!is_user_alive(attacker))
              return;

       // 攻击者正在使用小刀
       if (get_user_weapon(attacker) == CSW_KNIFE)
       {
              // 从资源物件中获取 "shockwave" 的 spr
              new sprite = AssetsGetSprite(g_oAssets, "shockwave");
              if (sprite)
              {
                     // 获取玩家身处的座标
                     static Float:origin[3];
                     pev(attacker, pev_origin, origin);

                     // 在玩家的位置制造一个冲击波
                     message_begin_f(MSG_PVS, SVC_TEMPENTITY, origin);
                     write_byte(TE_BEAMCYLINDER); // TE id
                     write_coord_f(origin[0]); // x
                     write_coord_f(origin[1]); // y
                     write_coord_f(origin[2]); // z
                     write_coord_f(origin[0]); // x axis
                     write_coord_f(origin[1]); // y axis
                     write_coord_f(origin[2] + 250.0); // z axis
                     write_short(sprite); // sprite
                     write_byte(0); // startframe
                     write_byte(0); // framerate
                     write_byte(10); // life
                     write_byte(30); // width
                     write_byte(0); // noise
                     write_byte(200); // red
                     write_byte(200); // green
                     write_byte(200); // blue
                     write_byte(200); // brightness
                     write_byte(0); // speed
                     message_end();
              }
       }
}

public OnEmitSound(id, channel, const sample[], Float:volume, Float:attn, flags, pitch)
{
       // 检查生存
       if (!is_user_alive(id))
              return FMRES_IGNORED;
       
       // weapons/
       if (strlen(sample) > 8)
       {
              // 小刀打到墙
              if (equal(sample[8], "knife_hitwall", 13))
              {
                     // 从资源物件在 "knife_hitwall" 中随机获取一个音效 (为何随机? 因为音效可多于一个)
                     static sound[32];
                     if (AssetsGetRandomSound(g_oAssets, "knife_hitwall", sound, charsmax(sound)))
                     {
                            // 取代原本的音效
                            emit_sound(id, channel, sound, volume, attn, flags, pitch);
                            return FMRES_SUPERCEDE;
                     }
              }
              
              // 小刀挥空气
              if (equal(sample[8], "knife_slash", 11))
              {
                     // 从资源物件在 "knife_spk" 中随机获取一个 generic 档 (为何随机? 因为音效可多于一个)
                     static spk[32];
                     if (AssetsGetRandomGeneric(g_oAssets, "knife_spk", spk, charsmax(spk)))
                     {
                            // 播放音效
                            client_cmd(0, "spk %s", spk);

                            // 阻止原本的声音播放
                            return FMRES_SUPERCEDE;
                     }
              }
       }

       return FMRES_IGNORED;
}

public OnEmitSound(id, channel, const sample[], Float:volume, Float:attn, flags, pitch)
{
       ...
       if (equal(sample[8], "knife_hitwall", 13))
       {
              if (g_aHitWallSound != Invalid_Array)
              {
                     static sound[64];
                     ArrayGetRandomString(g_aHitWallSound, sound, charsmax(sound));
                     emit_sound(id, channel, sound, volume, attn, flags, pitch);
                     return FMRES_SUPERCEDE;
              }
       }
       if (equal(sample[8], "knife_slash", 11))
       {
              if (g_aSlashSound != Invalid_Array)
              {
                     static sound[64];
                     ArrayGetRandomString(g_aSlashSound, sound, charsmax(sound));
                     client_cmd(0, "spk %s", sound);
                     return FMRES_SUPERCEDE;
              }
       }
}