#include <amxmodx>
#include <oo>

public plugin_init()
{
       // 掛鉤 Animal@Ctor() 的建構子
       oo_hook_ctor("Animal", "Ctor", "OnAnimalCtor");

       // 掛鉤 Dog@MakeSound() 方法 (post事件)
       oo_hook_mthd("Dog", "MakeSound", "OnDogMakeSound_Post", 1);

       // 掛鉤 Snake@GetLegs() 方法
       oo_hook_mthd("Snake", "GetLegs", "OnSnakeGetLegs_1");
       oo_hook_mthd("Snake", "GetLegs", "OnSnakeGetLegs_2");

       // 掛鉤 Snake@Test() 方法
       oo_hook_mthd("Snake", "Test", "OnSnakeTest");

       // 掛鉤 Animal@Dtor() 的解構子
       oo_hook_dtor("Animal", "OnAnimalDtor");
}

public OnAnimalCtor(const name[], age)
{
       server_print("OnAnimalCtor(name=%s, age=%d)", name, age);
}

public OnDogMakeSound_Post(msg[], len)
{
       server_print("OnDogMakeSound_Post(msg=%s, len=%d)", msg, len);
}

public OnSnakeGetLegs_1()
{
       server_print("OnSnakeGetLegs_1()");
       oo_hook_set_return(369); // 改變這方法原本回傳的值
       return OO_CONTINUE;
}

public OnSnakeGetLegs_2()
{
       server_print("OnSnakeGetLegs_2() => oo_hook_get_return()=%d", 
              oo_hook_get_return()); // 獲取之前改變了的回傳值

       return OO_SUPERCEDE; // 阻止原本這方法的執行
}

public OnSnakeTest(a, &b, const c[], d[], e[5])
{
       server_print("OnSnakeTest(%d, %d, %s, %s, {%d,%d,%d,%d,%d})", a, b, c ,d, e[0], e[1], e[2], e[3], e[4]);

       // 改變第 1 個參數 a 的值做 11
       oo_hook_set_param(1, OO_CELL, 11);

       // 改變第 2 個參數 b 的值做 22 (因為類型是 OO_BYREF 可以直接改)
       b = 22;

       // 改變第 3 個參數 c 的值做 "33"
       oo_hook_set_param(3, OO_STRING, "33");

       // 改變第 4 個參數 d 的值做 "44" (因為類型是 OO_STRING_REF 可以直接改)
       copy(d, 31, "44");

       // 改變第 5 個參數 e 的值做 {11, 22, 33, 44, 55}
       new arr[5] = {11, 22, 33, 44, 55};
       e = arr; // 因為類型是 OO_ARRAY 可以直接改
}

public OnAnimalDtor()
{
       server_print("OnAnimalDtor()");
}