下面是引用 chuchung712 于 2010-07-18 16:51 发表的 :
因为大神的改后座力插件是
复制程式

RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_???", "fw_WeapPriAttack") 
RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_???", "fw_WeapPriAttack_Post", 1)

所以我把,1拿掉了...
有关系的吗？

public plugin_init()
{
 register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
 
 new cvar_string[32]
 for (new i = 0; i < sizeof weapon_classname; i++)
 {
  if (strlen(weapon_classname[ i ]) == 0)
   continue;
  
  formatex(cvar_string, charsmax(cvar_string), "weap_%s_recoil", weapon_classname[ i ][7])
  g_weap_recoil[ i ] = register_cvar(cvar_string, weapon_recoil[ i ])
  
  RegisterHam(Ham_Weapon_PrimaryAttack, weapon_classname[ i ], "fw_WeapPriAttack", 1)
 }
}

/**
 * Hooks the virtual table for the specified entity class.
 * An example would be: RegisterHam(Ham_TakeDamage, "player", "player_hurt");
 * Look at the Ham enum for parameter lists.
 *
 * @param function The function to hook.
 * @param EntityClass The entity classname to hook.
 * @param callback The forward to call.
 * @param post  Whether or not to forward this in post.
 * @return   Returns a handle to the forward.  Use EnableHamForward/DisableHamForward to toggle the forward on or off.
 */
native HamHook:RegisterHam(Ham:function, const EntityClass[], const Callback[], Post=0);

下面是引用 chuchung712 于 2010-07-18 17:24 发表的 :
？！
莫非被骗了... ？！

我手边的改后座力： (注解是我删掉的、不想占空间太多)
复制程式

 #include <amxmodx> 
#include <fakemeta> 
#include <hamsandwich> 
#include <xs> 

// plugin's main information 
#define PLUGIN_NAME "[CS] Weapon Recoil Set" 
#define PLUGIN_VERSION "1.0" 
#define PLUGIN_AUTHOR "Jim" 

// Weapons Offsets 
const m_weapId = 43 
const OFFSET_LINUX_WEAPONS = 4 

// Weapons calssname 
new const weapon_classname[][] = { "", "weapon_p228", "", "weapon_scout", "", "weapon_xm1014", "", "weapon_mac10", 
    "weapon_aug", "", "weapon_elite", "weapon_fiveseven", "weapon_ump45", "weapon_sg550", "weapon_galil", "weapon_famas", 
    "weapon_usp", "weapon_glock18", "weapon_awp", "weapon_mp5navy", "weapon_m249", "weapon_m3", "weapon_m4a1", 
    "weapon_tmp", "weapon_g3sg1", "", "weapon_deagle", "weapon_sg552", "weapon_ak47", "", "weapon_p90" } 

// Recoil set (正常后座力=1.0 , 后座力减半=0.5 , 无后座力=0.0 , 无设定=-1.0) 
new const weapon_recoil[][] = { 
    "-1.0",     //----- 
    "-1.0",     //p228 
    "-1.0",     //----- 
    "-1.0",     //scout 
    "-1.0",     //----- 
    "-1.0",     //xm1014 
    "-1.0",     //----- 
    "-1.0",     //mac10 
    "-1.0",     //aug 
    "-1.0",     //----- 
    "-1.0",     //elites 
    "-1.0",     //fiveseven 
    "-1.0",     //ump45 
    "-1.0",     //sg550 
    "-1.0",     //galil 
    "-1.0",     //famas 
    "-1.0",     //usp 
    "-1.0",     //glock 
    "-1.0",     //awp 
    "-1.0",     //mp5navy 
    "-1.0",     //m249 
    "-1.0",     //m3 
    "-1.0",     //m4a1 
    "-1.0",     //tmp 
    "-1.0",     //g3sg1 
    "-1.0",     //----- 
    "-1.0",     //deagle 
    "-1.0",     //sg552 
    "-1.0",     //ak47 
    "-1.0", //----- 
    "-1.0"     //p90 
} 

new g_weap_recoil[sizeof weapon_classname] 
new Float:user_punchangle[33][3] 

public plugin_init() 
{ 
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR) 
    
    new cvar_string[32] 
    for (new i = 0; i < sizeof weapon_classname; i++) 
    { 
        if (strlen(weapon_classname[i]) == 0) 
              continue; 
          
        formatex(cvar_string, charsmax(cvar_string), "weap_%s_recoil", weapon_classname[i][7]) 
        g_weap_recoil[i] = register_cvar(cvar_string, weapon_recoil[i]) 
          
        RegisterHam(Ham_Weapon_PrimaryAttack, weapon_classname[i], "fw_WeapPriAttack") 
        RegisterHam(Ham_Weapon_PrimaryAttack, weapon_classname[i], "fw_WeapPriAttack_Post", 1) 
    } 
} 

public fw_WeapPriAttack(weapon) 
{ 
    if (!pev_valid(weapon)) 
        return HAM_IGNORED; 
    
    static owner 
    owner = pev(weapon, pev_owner) 
    
    pev(owner, pev_punchangle, user_punchangle[owner]) 
    
    return HAM_IGNORED; 
} 

public fw_WeapPriAttack_Post(weapon) 
{ 
    if (!pev_valid(weapon)) 
        return HAM_IGNORED; 
    
    static owner 
    owner = pev(weapon, pev_owner) 
    
    static weap_id 
    weap_id = fm_get_weaponid(weapon) 
    
    static Float:multiplier 
    multiplier = get_pcvar_float(g_weap_recoil[weap_id]) 
    
    //if (multiplier == -1.0) 
    if (multiplier < 0.0) 
        return HAM_IGNORED; 
    
    new Float:punchangle[3] 
    pev(owner, pev_punchangle, punchangle) 
    xs_vec_sub(punchangle, user_punchangle[owner], punchangle) 
    xs_vec_mul_scalar(punchangle, multiplier, punchangle) 
    xs_vec_add(punchangle, user_punchangle[owner], punchangle) 
    set_pev(owner, pev_punchangle, punchangle) 
    
    return HAM_IGNORED; 
} 

stock fm_get_weaponid(entity) 
{ 
    return get_pdata_int(entity, m_weapId, OFFSET_LINUX_WEAPONS); 
}

--------------------------------------------------------------------------------

但我本来就有加1的

为什么也没效果



话说 fw_WeapPriAttack_Post 跟 fw_WeapPriAttack 有分别的

      RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_ak47", "fw_WeapPriAttack", 1) 
... 
public fw_WeapPriAttack(weapon) 
{ 
     if (!pev_valid(weapon)) 
           return HAM_IGNORED; 
      
     static owner 
     owner = pev(weapon, pev_owner) 
      
     static szWeapID 
     szWeapID = get_user_weapon(owner, szClip, szAmmo) 
      
     if (g_mode_aim[owner] && (szWeapID == CSW_AK47)) 
     { 
           static Float:punchangle[3] // 假设Array 
           pev(owner, pev_punchangle, punchangle) // 将画面的角度导入假设的Array中 
           punchangle[0] *= get_pcvar_num(cvar_multiiplier) // 倍数 
           punchangle[1] *= get_pcvar_num(cvar_multiiplier) // 倍数 
           punchangle[2] *= get_pcvar_num(cvar_multiiplier) // 倍数 
     } 
      
     return HAM_IGNORED; 
}

对不起!您没有登入,请先登入论坛

下面是引用 chuchung712 于 2010-07-18 18:05 发表的 :
[code]      RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_ak47", "fw_WeapPriAttack", 1)
...
public fw_WeapPriAttack(weapon)
{
     if (!pev_valid(weapon))
.......

下面是引用 a7811311622 于 2010-07-16 22:50 发表的 :
 
RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_???", "fw_WeapPriAttack")
回传值并不是只有ID这么单纯…这段回传的内容有点复杂…
「fw_WeapPriAttack(weapon)」里的回传值"weapon"其中的内容包括了武器属名…
例如"weapon_knife"…就算是同样武器…但是所持有的玩家ID值也不同…
.......